* -----------------------------------------.
* Tutorial 1 - Descriptives - Demo Syntax.
* -----------------------------------------.

* ------------------.
* --- UNIVARIATE ---.
* ------------------.


* 1 - a8 What is your favourite season?
  (Nominal; ordinal? (cyclical)).
freq /vars = a8.
GRAPH /BAR(SIMPLE)=COUNT BY a8 .



* 2 - b2 Do you snore?
  (Nominal; dichotmous).
freq / vars = b2.
GRAPH /BAR(SIMPLE)=COUNT BY b2 .



* 3 - b4 Do you believe in God?
   (Nominal).
freq / vars = b4.
* Recode into ordinal.
RECODE b4 (1=1)  (2=3)  (3=2)  INTO  b4r .
variable label b4r 'Do you believe in God?'.
value labels b4r 1 'No' 2 'Sort of' 3 'Yes'.
freq / vars = b4r.

GRAPH /BAR(SIMPLE)=COUNT BY b4r .



* 4 - b9 At what age do you think you will die?
  (Continuous, ratio data).

desc /vars = b9 / statistics = mean stdev min max skewness kurtosis.

GRAPH /HISTOGRAM(NORMAL)=b9.
* (Note there is an outlier near 0 which is reducing the positive skew)



* 5 - b13 Femininity-Masculinity?
  (Likert scale; interval).

* Needs labels.
value labels b13 1 'Very feminine' 2 'Fairly feminine' 3 'Androgynous' 4 'Fairly masculine' 5 'Very masculine'.

freq vars = b13.

GRAPH /BAR(SIMPLE)=COUNT BY b13 .
* Note this is bimodal; split output (temporarily) by gender.

SORT CASES BY a1 .
SPLIT FILE
  SEPARATE BY a1 .

freq vars = b13.

GRAPH /BAR(SIMPLE)=COUNT BY b13 .

SPLIT FILE
  OFF.



* ------------------.
* --- BIVARIATE ---.
* ------------------.


* 6 - a1 (Gender) and a4 (Favourite colour)
  (nominal by nominal).
freq / vars = a1 a4.
CROSSTABS
  /TABLES=a1  BY a4
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT COLUMN
  /COUNT ROUND CELL .

GRAPH /BAR(GROUPED)=PCT BY a4 BY a1 .



* 7 - b10 (Psychology student status) and b7 (Exercise)
  (nominal by ratio).

freq / vars = b10. 
GRAPH /BAR(SIMPLE)=COUNT BY b10.
* Note misentered data, therefore recode.
RECODE b10  (0=0)  (1=1)  (ELSE=SYSMIS)  .
freq / vars = b10. 
GRAPH /BAR(SIMPLE)=COUNT BY b10.

desc /vars = b7 / statistics = mean stdev min max skewness kurtosis.
GRAPH /HISTOGRAM(NORMAL)=b7.

GRAPH
  /BAR(SIMPLE)=MEAN(b7) BY a1 .

MEANS
  TABLES=b7  BY b10
  /CELLS MEAN MEDIAN COUNT STDDEV SKEW KURT MIN MAX RANGE  .



* 8 - b14 (Physical health) and b15 (Mental health)
  (interval by interval).

freq / vars = b14 b15.

corr vars = b14 b15.

GRAPH
  /SCATTERPLOT(BIVAR)=b14 WITH b15
  /MISSING=LISTWISE .
* Note this scatterplot will need editing by going into 
  chart editor, then 
  double-click on a data point and 
  change to bins to allow representation of multiple data points.
GRAPH
  /SCATTERPLOT(BIVAR)=b7 WITH b9
  /MISSING=LISTWISE .



* 9 - b7 (Exercise) and b9 (At what age do you think you will die?)
  (ratio by ratio).

desc /vars = b7 b9 / statistics = mean stdev min max skewness kurtosis.
GRAPH /HISTOGRAM(NORMAL)=b7.
GRAPH /HISTOGRAM(NORMAL)=b9.

corr vars = b7 b9.

GRAPH
  /SCATTERPLOT(BIVAR)=b7 WITH b9
  /MISSING=LISTWISE .